Programm 4 - CAS PrePro

1 POKE 752,2:PRINT CHR$(125)
2 PRINT :PRINT :PRINT :PRINT "         ZEICHENPROGRAMM":PRINT :PRINT
3 PRINT "DIES IST EIN PROGRAMM ZUM MALEN."
4 PRINT "ZUM BEWEGEN DES PUNKTES BENUTZE"
5 PRINT "DEN JOYSTICK,DER IM JACKPORT 1 STECKT.";
6 PRINT "ZUM ZEICNEN DRUECKE DEN FEUERKNOPF AM"
7 PRINT "JOYSTICK.ZUM LOESCHEN DRUECKE DIE OPTION-TASTE."
8 PRINT "ZUM STARTEN DES PROGRAMMES,DRUECKE"
9 PRINT "DIE START-TASTE.":GOSUB 500
10 GRAPHICS 8+16
11 SETCOLOR 2,0,0
12 X=10:Y=10:X1=10:Y1=10
15 PRINT #6;CHR$(125)
16 PLOT 0,0
17 DRAWTO 319,0
18 DRAWTO 319,181
19 DRAWTO 0,181:DRAWTO 0,0
20 GOSUB 1000
30 IF F1=0 THEN GOTO 60
35 GOSUB 550
40 COLOR 0
50 PLOT X1,Y1
60 COLOR 1
70 PLOT X,Y
80 X1=X:Y1=Y
90 GOSUB 550
100 GOTO 20
110 END 
500 QW=PEEK(53279)
510 IF QW<>6 THEN GOTO 500
520 RETURN 
550 QW=PEEK(53279)
560 IF QW=3 THEN POP :GOTO 11
570 RETURN 
1000 S1=STICK(0)
1010 F1=STRIG(0)
1020 IF S1=14 THEN Y=Y-1
1030 IF S1=6 THEN X=X+1:Y=Y-1
1040 IF S1=7 THEN X=X+1
1050 IF S1=5 THEN X=X+1:Y=Y+1
1060 IF S1=13 THEN Y=Y+1
1070 IF S1=9 THEN X=X-1:Y=Y+1
1080 IF S1=11 THEN X=X-1
1090 IF S1=10 THEN X=X-1:Y=Y-1
1100 IF X<0 THEN X=X+1
1110 IF Y<0 THEN Y=Y+1
1120 IF X>319 THEN X=X-1
1130 IF Y>181 THEN Y=Y-1
1140 RETURN